1 PRINT TAB(26)"MATPUZLE"
2 PRINTTAB(20)"CREATIVE COMPUTING"
3 PRINT TAB(18)"MORRISTOWN, NEW JERSEY"
4 PRINT:PRINT
10 DIM A$(6),B$(6,6),C(6,6),C$(6,6)
20 PRINT"THIS IS A PUZZLE-MAKING GAME."
30 PRINT"YOU INPUT UP TO SIX WORDS, UP TO SIX"
40 PRINT"LETTERS EACH, AND EQUAL IN LENGTH."
50 PRINT"THE COMPUTER WILL SCRAMBLE THEN AND"
60 PRINT"TRINT THEM IN A MATRIX.  THE COMPUTER "
70 PRINT"WILL ALSO PRINT A CORRESPONDING NUMBER"
80 PRINT"BOARD.  WHEN IT STOPS TEAR IT AND GIVE IT"
90 PRINT"TO A FRIEND."
100 PRINT"HOW MANY WORDS DO YOU WANT (UP TO 6)";
105 INPUT W
110 PRINT"HOW MANY LETTERS IN EACH WORD (MUST BE SAME)";
115 INPUT L
120 PRINT"TYPE ONE";L;"LETTER WORD ON EACH LINE"
130 FOR X=1 TO W
140 INPUT A$(X)
150 NEXT X
160 FOR X=1 TO W
170 FOR  Y=1 TO L
180 C$(X,Y)=MID$(A$(X),Y,1):B$(X,Y)=MID$(A$(X),Y,1)
190 NEXT Y
200 NEXT X
210 PRINT
215 FOR P=1 TO 28
220 PRINT"-";
221 NEXT P
225 PRINT TAB(29)"( TEAR HERE )";
226 FOR P1=1 TO 27
227 PRINT TAB(43)"-";
228 NEXT P1
230 PRINT
240 FOR Z=1 TO 60
250 F=INT(RND(1)*W+1)
260 D=INT(RND(1)*W+1)
270 G=INT(RND(1)*L+1)
280 E=INT(RND(1)*L+1)
290 J$=B$(F,G)
300 B$(F,G)=B$(D,E)
310 B$(D,E)=J$
320 NEXT Z
330 PRINT TAB(4);
340 FOR Z1=1 TO L
350 PRINT TAB(5);Z1;" ";
360 NEXT Z1
370 PRINT
380 PRINT
390 FOR Z2=1 TO W
400 PRINT Z2;"   ";
410 FOR Z3=1 TO L
420 PRINT B$(Z2,Z3);"   ";
430 NEXT Z3
440 PRINT
450 PRINT
460 NEXT Z2
470 PRINT
480 PRINT
490 PRINT
500 FOR P=1 TO L
510 FOR Q=1 TO W
520 T=0
530 FOR R=1 TO W
540 FOR S=1 TO L
550 IF T=1 THEN 600
560 IF B$(R,S)<>C$(Q,P)THEN 600
570 C(Q,P)=R+S
580 T=1
590 B$(R,S)=" "
600 NEXT S
610 NEXT R
620 NEXT Q
630 NEXT P
640 FOR X=1 TO W
650 PRINT TAB(3)
660 FOR M=1 TO L
670 IF C(X,M)>9 THEN 700
680 PRINT C(X,M);"     ";
690 GOTO 710
700 PRINT C(X,M);"    ";
710 NEXT M
720 PRINT:PRINT
730 PRINT TAB(2);
740 FOR M1=1 TO L
750 PRINT"-----";"   ";
760 NEXT M1
770 PRINT
780 NEXT X
790 PRINT
800 PRINT
810 PRINT"THE NUMBER ABOVE EACH DASH IS THE SUM OF TWO COORDINATES OF"
820 PRINT"THE POINT ON THE MATRIX WHERE THE CORRECT LETTER FOR THAT "
830 PRINT"SPOT WILL APPEAR.  THE PROBLEM IS THAT THE SUM OF SOME "
840 PRINT"COORDINATES ARE THE SAME SO SEVERAL LETTERS COULD FIT. SO "
850 PRINT"TRY NOW TO FIND WHAT WORDS WERE USED AND SOLVE THE PUZZLE"
855 PRINT"-- GOOD LUCK"
860 PRINT"DO YOU WANT ANOTHER RUN";
861 INPUT Y9$
870 IF Y9$="YES" THEN 100
880 END